《WEB程序设计与应用》网络教学平台

html>
<head>
<title> Response.Write用法示例</title>
</head>
<body>
<%
Dim name,age
Name="赵芳" '这里为了简单，直接赋值了。其实一般是传过来的
Age=20
Response.Write name & "您好，欢迎您"
Response.Write "，您的年龄是" & Cstr(age)
%>
<p>
<%=name & "您好，欢迎您"%>
<%="，您的年龄是" & Cstr(age)%>
</body>
</html>

2、

<% Response.Buffer=True '注意，必须有这句话 %>
<html>
<head>
<title> Response.Redirect用法示例</title>
</head>
<body>
<%
Dim user_type
user_type="teacher" '用户类型，一般应该传过来，这里简单赋值了
If user_type="teacher" Then
Response.Redirect "teacher.asp" '将教师用户引导至教师网页
Else
Response.Redirect "student.asp" '将学生用户引导至学生网页
End If
%>
</body>
</html>

请找出并分析其中使用的Response对象的代码：

<% Option Explicit %>
<html>
<head>
<title>查询全部成员</title>
</head>
<body>
<h2 align="center">成员列表</h2>
<%
'先输出表格的标题栏
%>
<center>
<table border="0" width="90%">
<tr bgcolor="#B7B7B7" align="center">
<td width=10%>姓名</td>
<td width=20%>电话</td>
<td width=30%>email</td>
<td width=20%>住址</td>
<td width=20%>简介</td>
</tr>
<%
Dim db,rs,strSql
'建立Connection对象
Set db=Server.CreateObject("ADODB.Connection")
db.Open "DSN=newaddr" '这里利用新数据源
'建立Recordset对象
Set rs=Server.CreateObject("ADODB.Recordset")
strSql ="Select * From users Order By name " '以姓名为序排列
rs.Open strSql,db,1 '因为要分页显示，所以用键盘指针

'下面查询记录，如果非空就显示记录，如果是空的，给出提示信息
If rs.Bof Or rs.Eof Then
Response.Write "现在还没有数据"
Else
'以下主要为了分页显示
dim page_size '定义每页多少条记录变量
dim page_no '定义当前是第几页变量
dim page_total '定义总页数变量
page_size=10 '每页显示10条记录
'如果第一次打开，则page_no为1，否则由传回的参数决定
If Request.QueryString("page_no")="" Then
page_no=1
Else
page_no=Cint(Request.QueryString ("page_no")) '用Cint将字符串变为整数
End If
rs.PageSize=page_size '设置每页多少条记录
page_total=rs.PageCount '返回总页数
rs.AbsolutePage=page_no '设置当前显示第几页
'下面一段利用表格显示当前页的所有记录
Dim I
I=page_size '该变量用来控制显示当前页记录
Do While Not rs.Eof And I>0 '循环直到当前页结束或文件结尾
I=I-1
'下面将利用表格输出名单
Response.Write "<tr bgcolor='#00CCFF' align='center'>"
Response.Write "<td>" & rs("name") & "</td>"
Response.Write "<td>" & rs("tel") & " </td>"
Response.Write "<td><a href='mailto:" & rs("email") & "'>" & rs("email") & "</td>"
Response.Write "<td>" & rs("home") & "</td>"
Response.Write "<td>" & rs("intro") & "</td>"
Response.Write "</tr>"
rs.MoveNext
Loop
Response.Write "</table>" '表格结束
Response.Write "<p>请选择数据页: "
'输出有关页数信息，从1到总页数循环，如不是当前页，就加上超链接
For I=1 To page_total
If I=page_no Then
Response.Write I & "&nbsp"
Else
Response.Write "<a href='list.asp?page_no=" & I & "'>" & I & "</a>&nbsp"
End If
Next
End if
'关闭对象
rs.Close
Set rs=nothing
db.Close
Set db=nothing
%>
</center>
</body>
</html>

~ 江西信息应用技术职业学院信息技术系制作 ~

E-Mail:lxlz2050@163.net Tel:0791-5275546